Howdy, Stranger!

It looks like you're new here. If you want to get involved, click one of these buttons!

Categories

Compile error

peljopeljo Member Posts: 6
I have copied form Internet a function that creates a toolbar on the fly.However, when i use it i get the following error : Compile error : user defined type not defined. Should i refer to some library ?
Here is the function :


' ----- Beginning Of Code -----
' ,This sample creates a custom toolbar with menu items (with sub menu's within) amd a dropdown box with choices, code sample also includes the
' event andling for the items. Run CreateToolbarExample - this will create the toolbar with menu items MenuEvents - is the event handling macro which handles all events
' emoveMenu - Deletes the custom toolbar


Public Function CreatePopupToolbarExample()
Dim CustomToolBar As CommandBar
Dim MainCustomBar As CommandBarPopup
Dim SubMenuItem As CommandBarButton
Dim SubMenuPopUp As CommandBarPopup
Dim SubMenuPopUpItem As CommandBarButton
Dim DropDownList As CommandBarControl

Dim strToolBar As String
Dim iCount As Integer

' Replace "My Toolbar" with a name
' you want to use for your toolbar.
strToolBar = "My Toolbar"

' Create and display the Toolbar.
Set CustomToolBar = CommandBars.Add(Name:=strToolBar, _
Position:=msoBarFloating)
CustomToolBar.Visible = True

' Create Main PopUp Menu on Toolbar.
Set MainCustomBar = CustomToolBar.Controls.Add(Type:=msoControlPopup)
MainCustomBar.Caption = "Main Menu"
' Create Dropdown list on toolbar
Set DropDownList = CustomToolBar.Controls.Add(Type:=msoControlDropdown)

' Add a Menu Button and a Popup
With MainCustomBar.Controls
Set SubMenuItem = .Add(Type:=msoControlButton)
Set SubMenuPopUp = .Add(Type:=msoControlPopup)
End With

' Set properties for the sub button and popup menus.
With SubMenuItem
.Caption = "Sub Menu Item"
.Style = msoButtonCaption
.OnAction = "MenuEvents" ' <- Macro to run when clicked.
End With

With SubMenuPopUp
.Caption = "Sub Menu Popup"
' This optional can be used to invoke macro which toggles
' the state of child controls.
.OnAction = "MenuEvents"
End With

' Add item to Sub Menu
With SubMenuPopUp.Controls
Set SubMenuPopUpItem = .Add(Type:=msoControlButton)
End With

With SubMenuPopUpItem
.Caption = "Sub Menu Popup Item"
.OnAction = "MenuEvents" ' <- Macro to run when clicked.
End With

' Create a combo box which lists the options.

With DropDownList
.AddItem "Choice A"
.AddItem "Choice B"
.Caption = "Choices"
.TooltipText = "Select choice from the list"
.Width = 120
' default value to show
.ListIndex = 1
.OnAction = "MenuEvents"
End With

End Function

Sub MenuEvents()
'Handler for the event when user clicks on the toolbar options
Dim cmdBCtl As CommandBarControl
Set cmdBCtl = Application.CommandBars.ActionControl
' Determine the caption of the control that was clicked.
Select Case cmdBCtl.Caption

Case "Choices"
With cmdBCtl
Select Case .ListIndex
Case 1
MsgBox "You selected 1st item in dropdown list", _
vbInformation, "Menu Choice"
Case 2
MsgBox "You selected 2nd item in dropdown list", _
vbInformation, "Menu Choice"
End Select
End With
Case "Sub Menu Item"
MsgBox "You selected item:" & "Sub Menu Item", _
vbInformation, "Menu Choice"

Case "Sub Menu Popup"
' Do preprocessing, adding/deleting/
' enabling/disabling child items in the popup.
Debug.Print "Sub Menu Popup"
Case "Sub Menu Popup Item"
MsgBox "You selected item in the popup", _
vbInformation, "Menu Choice"
End Select
End Sub

Sub RemoveMenu()
On Error Resume Next
Application.CommandBars("My Toolbar").Delete
End Sub

' ----- End Of Code -----

Comments

  • dokken2dokken2 Member Posts: 532
    [b][red]This message was edited by dokken2 at 2006-5-25 8:12:38[/red][/b][hr]
    : I have copied form Internet a function that creates a toolbar on the fly.However, when i use it i get the following error : Compile error : user defined type not defined. Should i refer to some library ?
    : Here is the function :
    :
    :

    add a reference to the "microsoft office xx.x object library" where xx.x equals the version of office, ie: 10.0, 11.0, etc.

    see http://techrepublic.com.com/5100-6329-5034767.html for details.

    its a pretty cool and easy to use once you have the proper reference.


Sign In or Register to comment.